Nápověda LibreOffice 25.2
Vrací počet buněk, které splňují kritéria z více oblastí.
Vrátí pravděpodobnost výsledku vypočtenou za použití binomického rozdělení.
B(Pokusy; SP; T1 [; T2])
Pokusů je počet nezávislých pokusů.
SP je pravděpodobnost úspěchu při každém pokusu.
T1 určuje dolní mez pro počet úspěšných pokusů.
T2 (nepovinné) určuje horní mez pro počet úspěšných pokusů.
Jaká je pravděpodobnost, že při deseti hodech kostkou padne šestka právě dvakrát? Pravděpodobnost, že padne šestka (nebo jakékoli jiné číslo), je 1/6. Všechny tyto okolnosti jsou využity v následujícím vzorci:
=B(10;1/6;2) vrátí pravděpodobnost 29 %.
Vrátí beta rozdělení.
BETA.DIST(Číslo; Alfa; Beta; Kumulativní [; Začátek [; Konec]])
Číslo (vyžadováno) je hodnota mezi Začátkem a Koncem, pro kterou se funkce vyhodnotí.
Alfa (vyžadováno) je parametr rozdělení.
Beta (vyžadováno) je parametr rozdělení.
Kumulativní (vyžadováno) může být 0 nebo Nepravda pro výpočet hustoty pravděpodobnosti. Pro jakoukoliv jinou hodnotu nebo Pravda se vypočte distribuční funkce.
Začátek (nepovinné) je dolní mez pro Číslo.
Konec (nepovinné) je horní mez pro Číslo.
Pokud jsou parametry funkcí LibreOffice Calc označeny jako „nepovinné“, je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako „nepovinné“, je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.
=BETA.DIST(2;8;10;1;1;3) vrátí hodnotu 0,6854706
=BETA.DIST(2;8;10;0;1;3) vrátí hodnotu 1,4837646
COM.MICROSOFT.BETA.DIST
Vrátí hodnoty inverzní distribuční funkce beta rozdělení.
BETA.INV(Číslo; Alfa; Beta [; Začátek [; Konec]])
Číslo je pravděpodobnost odpovídající beta rozdělení pro zadané argumenty Alfa a Beta.
Alfa je vždy kladný parametr beta rozdělení.
Beta je vždy kladný parametr beta rozdělení.
Začátek (nepovinné) je dolní mez rozsahu výstupu distribuční funkce. Je-li vynecháno, výchozí hodnotou je 0.
Konec (nepovinné) je horní mez rozsahu výstupu distribuční funkce. Je-li vynecháno, výchozí hodnotou je 1.
Pokud jsou parametry funkcí LibreOffice Calc označeny jako „nepovinné“, je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako „nepovinné“, je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.
=BETA.INV(0,5;5;10) vrátí hodnotu 0,3257511553.
COM.MICROSOFT.BETA.INV
Vrátí beta rozdělení.
BETADIST(Číslo; Alfa; Beta [; Začátek [; Konec [; Kumulativní]]])
Číslo je hodnota mezi Začátkem a Koncem, pro kterou se funkce vyhodnotí.
Alfa je parametr rozdělení.
Beta je parametr rozdělení.
Začátek (nepovinné) je dolní mez pro Číslo.
Konec (nepovinné) je horní mez pro Číslo.
Kumulativní (nepovinné) může být 0 nebo Nepravda pro výpočet hustoty pravděpodobnosti. Pro jakoukoliv jinou hodnotu, Pravda nebo vynechaný parametr se vypočte distribuční funkce.
Pokud jsou parametry funkcí LibreOffice Calc označeny jako „nepovinné“, je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako „nepovinné“, je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.
=BETADIST(0,75;3;4) vrátí hodnotu 0,96.
Vrátí hodnoty inverzní distribuční funkce beta rozdělení.
BETAINV(Číslo; Alfa; Beta [; Začátek [; Konec]])
Číslo je pravděpodobnost odpovídající beta rozdělení pro zadané argumenty Alfa a Beta.
Alfa je vždy kladný parametr beta rozdělení.
Beta je vždy kladný parametr beta rozdělení.
Začátek (nepovinné) je dolní mez rozsahu výstupu distribuční funkce. Je-li vynecháno, výchozí hodnotou je 0.
Konec (nepovinné) je horní mez rozsahu výstupu distribuční funkce. Je-li vynecháno, výchozí hodnotou je 1.
Pokud jsou parametry funkcí LibreOffice Calc označeny jako „nepovinné“, je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako „nepovinné“, je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.
=BETAINV(0,5;5;10) vrátí hodnotu 0,3257511553.
Vrátí hodnoty pravděpodobnosti binomického rozdělení.
BINOM.DIST(X; Pokusy; SP; C)
X je počet úspěšných pokusů.
Pokusů je počet nezávislých pokusů.
SP je pravděpodobnost úspěchu při každém pokusu.
Pro C = 0 se spočítá pravděpodobnost jediného jevu a pro C = 1 se spočítá kumulativní pravděpodobnost.
=BINOM.DIST(A1;12;0,5;0) ukáže (je-li v A1 zadána hodnota mezi 0 a 12) pravděpodobnost toho, že při 12 hodech mincí padne Panna právě tolikrát, kolik je zadáno v A1.
=BINOM.DIST(A1;12;0,5;1) ukáže kumulativní pravděpodobnost pro stejný případ. Je-li například A1 = 4, kumulativní pravděpodobnost je tvořena případy, že padne 0, 1, 2, 3 nebo 4krát Panna (nevýlučné nebo).
COM.MICROSOFT.BINOM.DIST
Vrátí nejmenší hodnotu, pro kterou je kumulativní binomické rozdělení menší nebo rovno zadanému kritériu.
BINOM.INV(Pokusy; SP; Alfa)
Pokusy je celkový počet pokusů.
SP je pravděpodobnost úspěchu při každém pokusu.
Alfa je mezní pravděpodobnost, která má být dosažena nebo překročena.
=BINOM.INV(8;0,6;0,9) vrátí 7, nejmenší hodnotu, pro kterou je kumulativní binomické rozdělení větší nebo rovno hodnotě kritéria.
COM.MICROSOFT.BINOM.INV
Vrátí hodnoty pravděpodobnosti binomického rozdělení.
BINOMDIST(X; Pokusy; SP; C)
X je počet úspěšných pokusů.
Pokusy je počet nezávislých pokusů.
SP je pravděpodobnost úspěchu při každém pokusu.
Pro C = 0 se spočítá pravděpodobnost jediného jevu a pro C = 1 se spočítá kumulativní pravděpodobnost.
=BINOMDIST(A1;12;0,5;0) ukáže (je-li v A1 zadána hodnota mezi 0 a 12) pravděpodobnost toho, že při 12 hodech mincí padne Panna právě tolikrát, kolik je zadáno v A1.
=BINOMDIST(A1;12;0,5;1) ukáže kumulativní pravděpodobnost pro stejný případ. Je-li například A1 = 4, kumulativní pravděpodobnost je tvořena případy, že padne 0, 1, 2, 3 nebo 4krát Panna (nevýlučné nebo).
Vrátí na základě dané hodnoty chí kvadrátu hodnotu pravděpodobnosti toho, že hypotéza platí. CHIDIST porovnává zadanou hodnotu chí kvadrátu pro náhodný výběr, která se vypočte jako součet řady (pozorovaná hodnota - očekávaná hodnota)^2/očekávaná hodnota, s teoretickým rozdělením chí kvadrát. Z toho se určí pravděpodobnost chyby ověřované hypotézy.
Pravděpodobnost určenou CHIDIST je také možné určit pomocí CHITEST.
CHIDIST(Číslo; StupněVolnosti)
Číslo je hodnota chí kvadrátu náhodného výběru, která se použije k určení pravděpodobnosti chyby.
StupněVolnosti je počet stupňů volnosti experimentu.
=CHIDIST(13,27; 5) se rovná 0,02.
Je-li hodnota chí kvadrátu náhodného výběru rovna 13,27 a má-li experiment 5 stupňů volnosti, potom je hypotéza potvrzena s pravděpodobností chyby 2 %.
Vrátí inverzní distribuční funkci jednostranného rozdělení chí kvadrát.
CHIINV(Číslo; Stupně volnosti)
Číslo je hodnota pravděpodobnosti chyby.
Stupně volnosti je počet stupňů volnosti experimentu.
Kostka je vržena 1020krát. Čísla 1 až 6 padnou 195, 151, 148, 189, 183 a 154krát (pozorované hodnoty). Má se prověřit hypotéza, že kostka není zfalšovaná.
Rozdělení chí kvadrát náhodného výběru je dáno vztahem uvedeným výše. Vzhledem k tomu, že očekávaná hodnota (že padne určité číslo) je při n hodech kostkou rovna n krát 1/6, tzn. 1020/6 = 170, dává výše uvedený vztah hodnotu chí kvadrát rovnou 13,27.
Jestliže je (pozorovaná) hodnota chí kvadrát větší nebo rovna (teoretické) hodnotě chí kvadrát CHIINV, je nutno hypotézu zamítnout, poněvadž odchylka mezi teorií a experimentem je příliš velká. Je-li pozorovaná hodnota chí kvadrát menší než CHIINV, je hypotéza potvrzena se stanovenou pravděpodobností chyby.
=CHIINV(0,05;5) vrátí 11,07.
=CHIINV(0,02;5) vrátí 13,39.
Je-li pravděpodobnost chyby 5 %, není kostka v pořádku. Je-li pravděpodobnost chyby 2 %, není důvod k pochybnostem o pravosti kostky.
Vrátí hodnotu hustoty pravděpodobnosti nebo distribuční funkce pro rozdělení chí kvadrát.
CHISQ.DIST(Číslo; StupněVolnosti; Kumulativní)
Číslo je hodnota chí kvadrátu náhodného výběru, která se použije k určení pravděpodobnosti chyby.
StupněVolnosti je počet stupňů volnosti experimentu.
Kumulativní může být 0 nebo Nepravda pro výpočet hustoty pravděpodobnosti. Pro jakoukoliv jinou hodnotu nebo Pravda se vypočte distribuční funkce.
=CHISQ.DIST(3; 2; 0) se rovná 0,1115650801, hustotě pravděpodobnosti pro 2 stupně volnosti a hodnotu x = 3.
=CHISQ.DIST(3; 2; 1) se rovná 0,7768698399, distribuční funkci rozdělení chí kvadrát se 2 stupni volnosti pro hodnotu x = 3.
COM.MICROSOFT.CHISQ.DIST
Vrátí na základě dané hodnoty chí kvadrátu hodnotu pravděpodobnosti toho, že hypotéza platí. CHISQ.DIST.RT porovnává zadanou hodnotu chí kvadrátu pro náhodný výběr, která se vypočte jako součet řady (pozorovaná hodnota - očekávaná hodnota)^2/očekávaná hodnota, s teoretickým rozdělením chí kvadrát. Z toho se určí pravděpodobnost chyby ověřované hypotézy.
Pravděpodobnost určenou CHISQ.DIST.RT je také možné určit pomocí CHITEST.
CHISQ.DIST.RT(Číslo; StupněVolnosti)
Číslo je hodnota chí kvadrátu náhodného výběru, která se použije k určení pravděpodobnosti chyby.
StupněVolnosti je počet stupňů volnosti experimentu.
=CHISQ.DIST.RT(13,27; 5) se rovná 0,0209757694.
Je-li hodnota chí kvadrátu náhodného výběru rovna 13,27 a má-li experiment 5 stupňů volnosti, potom je hypotéza potvrzena s pravděpodobností chyby 2 %.
COM.MICROSOFT.CHISQ.DIST.RT
Vrátí inverzní distribuční funkci levostranného rozdělení chí kvadrát.
CHISQ.INV(Pravděpodobnost; StupněVolnosti)
Pravděpodobnost je hodnota pravděpodobnosti, pro kterou se má inverzní distribuční funkce rozdělení chí kvadrát vypočítat.
StupněVolnosti jsou stupně volnosti rozdělení chí kvadrát.
=CHISQ.INV(0,5;1) vrátí 0,4549364231.
COM.MICROSOFT.CHISQ.INV
Vrátí inverzní distribuční funkce jednostranného rozdělení chí kvadrát.
CHISQ.INV.RT(Číslo; StupněVolnosti)
Číslo je hodnota pravděpodobnosti chyby.
Stupně volnosti je počet stupňů volnosti experimentu.
Kostka je vržena 1020krát. Čísla 1 až 6 padnou 195, 151, 148, 189, 183 a 154krát (pozorované hodnoty). Má se prověřit hypotéza, že kostka není zfalšovaná.
Rozdělení chí kvadrát náhodného výběru je dáno vztahem uvedeným výše. Vzhledem k tomu, že očekávaná hodnota (že padne určité číslo) je při n hodech kostkou rovna n krát 1/6, tzn. 1020/6 = 170, dává výše uvedený vztah hodnotu chí kvadrát rovnou 13,27.
Jestliže je (pozorovaná) hodnota chí kvadrát větší nebo rovna (teoretické) hodnotě chí kvadrát CHIINV, je nutno hypotézu zamítnout, poněvadž odchylka mezi teorií a experimentem je příliš velká. Je-li pozorovaná hodnota chí kvadrát menší než CHIINV, je hypotéza potvrzena se stanovenou pravděpodobností chyby.
=CHISQ.INV.RT(0,05;5) vrátí 11,0704976935.
=CHISQ.INV.RT(0,02;5) vrátí 13,388222599.
Je-li pravděpodobnost chyby 5 %, není kostka v pořádku. Je-li pravděpodobnost chyby 2 %, není důvod k pochybnostem o pravosti kostky.
COM.MICROSOFT.CHISQ.INV.RT
Vrátí pravděpodobnost toho, že se náhodná rozdělení dvou testovaných řad liší, a to pomocí testu nezávislosti chí kvadrát. CHISQ.TEST vrátí pro data hodnotu distribuční funkce rozdělení chí kvadrát.
Pravděpodobnost určenou funkcí CHISQ.TEST lze také určit pomocí funkce CHISQ.DIST. V takovém případě však musí být jako parametr funkce zadána místo datové řady hodnota chí kvadrátu náhodného výběru.
CHISQ.TEST(DataB; DataE)
DataB je matice pozorování.
DataE je oblast očekávaných hodnot.
| Data_B (pozorovaná) | Data_E (očekávaná) | |
|---|---|---|
| 1 | 195 | 170 | 
| 2 | 151 | 170 | 
| 3 | 148 | 170 | 
| 4 | 189 | 170 | 
| 5 | 183 | 170 | 
| 6 | 154 | 170 | 
=CHISQ.TEST(A1:A6;B1:B6) se rovná 0,0209708029.. Tato pravděpodobnost je dostatečná pro tvrzení, že pro daná data má testovací statistika rozdělení chí kvadrát.
COM.MICROSOFT.CHISQ.TEST
Vrátí hodnotu hustoty pravděpodobnosti nebo distribuční funkce pro rozdělení chí kvadrát.
CHISQDIST(Číslo; Stupně volnosti [; Kumulativní])
Číslo je číslo, pro které má být funkce vypočítána.
Stupně volnosti je počet stupňů volnosti funkce chí kvadrát.
Kumulativní (nepovinné): Pro 0 nebo Nepravda se spočítá hustota pravděpodobnosti. Pro jiné hodnoty nebo nezadaný argument se spočítá distribuční funkce.
Vrátí inverzní funkci k CHISQDIST.
CHISQINV(Pravděpodobnost; Stupně volnosti)
Pravděpodobnost je hodnota pravděpodobnosti, pro kterou se vypočítá inverzní distribuční funkce rozdělení chí kvadrát.
Stupně volnosti je počet stupňů volnosti funkce chí kvadrát.
Vrátí pravděpodobnost toho, že se náhodná rozdělení dvou testovaných řad liší, a to pomocí testu nezávislosti chí kvadrát. CHITEST vrátí pro data hodnotu distribuční funkce rozdělení chí kvadrát.
Pravděpodobnost určenou funkcí CHITEST lze také určit pomocí funkce CHIDIST. V takovém případě však musí být jako parametr funkce zadána místo datové řady hodnota chí kvadrátu náhodného výběru.
CHITEST(DataB; DataE)
DataB je matice pozorování.
DataE je oblast očekávaných hodnot.
=CHITEST(A1:A6;B1:B6) se rovná 0,02. Tato pravděpodobnost je dostatečná pro tvrzení, že pro daná data má testovací statistika rozdělení chí kvadrát.
Zjistí, kolik čísel je v seznamu argumentů. Textové záznamy jsou ignorovány.
COUNT(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Hodnoty 2, 4, 6 a osm v polích Hodnota 1-4, se kterými má být proveden výpočet.
=COUNT(2;4;6;"osm") = 3. Počet čísel je tedy 3.
Spočte, kolik hodnot je v seznamu argumentů. Počítají se také textové záznamy, i když obsahují prázdný řetězec nebo řetězec délky 0. Je-li argumentem matice nebo odkaz, jsou prázdné buňky matice nebo odkazu ignorovány.
COUNTA(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Hodnoty 2, 4, 6 a osm v polích Hodnota 1-4, se kterými má být proveden výpočet.
=COUNTA(2;4;6;"osm") = 4. Počet hodnot je tedy 4.
Vrátí počet prázdných buněk.
COUNTBLANK(Oblast)
Vrátí počet prázdných buněk v oblasti Oblast.
=COUNTBLANK(A1:B2) vrátí 4, pokud jsou buňky A1, A2, B1 a B2 prázdné.
Vrátí počet buněk z dané oblasti, které splňují určitá kritéria.
COUNTIF(Oblast; Kritérium)
Oblast je oblast, která bude posuzována danými kritérii.
A1:A10 je oblast buněk obsahující čísla 2000 až 2009. Buňka B1 obsahuje číslo 2006. Do buňky B2 vložíte tento vzorec:
=COUNTIF(A1:A10;2006) - toto vrátí 1.
=COUNTIF(A1:A10;B1) - toto vrátí 1.
=COUNTIF(A1:A10;">=2006") - toto vrátí 4.
=COUNTIF(A1:A10;"<"&B1) - obsahuje-li B1 2006, výsledek bude 6.
=COUNTIF(A1:A10;C2), kde buňka C2 obsahuje text >2006, vrátí počet buněk v oblasti A1:A10, které jsou >2006.
Chcete-li spočítat pouze záporná čísla: =COUNTIF(A1:A10;"<0")
Vrátí exponenciální rozdělení.
EXPON.DIST(Číslo; Lambda; C)
Číslo je hodnota pro funkci.
Lambda je hodnota parametru.
C je logická proměnná udávající podobu funkce. Pro C = 0 se spočítá hustota pravděpodobnosti a pro C = 1 se spočítá distribuční funkce.
=EXPON.DIST(3;0,5;1) vrátí 0,7768698399.
COM.MICROSOFT.EXPON.DIST
Vrátí exponenciální rozdělení.
EXPONDIST(Číslo; Lambda; C)
Číslo je hodnota pro funkci.
Lambda je hodnota parametru.
C je logická proměnná udávající podobu funkce. Pro C = 0 se spočítá hustota pravděpodobnosti a pro C = 1 se spočítá distribuční funkce.
=EXPONDIST(3;0,5;1) vrátí 0,78.
Na základě známých hodnot X a Y vypočítá bod, ve kterém přímka protne osu Y.
INTERCEPT(DataY; DataX)
DataY je závislá množina pozorování nebo dat.
DataX je nezávislá množina pozorování nebo dat.
Je nutno použít názvy, pole nebo odkazy obsahující čísla. Také je možné zadat přímo čísla.
Pro výpočet průsečíku s osou Y použijte jako hodnoty Y oblast buněk D3:D9 a jako hodnoty X oblast buněk C3:C9 ze sešitu s příklady. Forma zápisu bude následující:
=INTERCEPT(D3:D9;C3:C9) = 2,15.
Vypočte druhou mocninu Pearsonova korelačního koeficientu na základě zadaných hodnot. RSQ (také nazývaný koeficient determinace) je míra závislosti a lze jej použít pro regresní analýzu.
RSQ(DataY; DataX)
DataY je matice nebo oblast bodových dat.
DataX je matice nebo oblast bodových dat.
=RSQ(A1:A20;B1:B20) vypočte koeficient determinace mezi množinami dat ve sloupcích A a B.